レコードセットをページングするには

Accessのデータベースado.mdbから得意先テーブルのレコードセットを作成して複数のページに分割して表示する方法を説明します。レコードセットの内容をHTMLページに表示させるとき、レコード数を制約しないと結果が表示されるまで時間がかかり過ぎて実用的ではありません。この場合、１回の要求で表示するレコード数を適当な範囲で制約することにより快適なレスポンスを保障することができます。

レコードセットを複数のページに分割して表示する場合、すべてアプリケーション側で対処する方法もありますが、RecordsetオブジェクトのPageSize, PageCount, AbsolutePageプロパティを使用することにより比較的簡単にページング処理を行うことができます。

●　ページ当たりのレコード数を固定とするサンプル

得意先テーブルのレコードセットをページ当たり10レコード単位で複数のページに分割して表示する方法を説明します。ここで紹介するサンプルは、ページを移動するために「Prev 1 2 3 4 5 Next」のようなハイパーリンクを表示します。3はカレントのページを意味します。Prevのリンクをクリックするとページ２を表示します。Nextのリンクをクリックするとページ４を表示します。ページ番号(1 2 4 5)のリンクをクリックすると対応するページを表示します。

Access + Webのダウンロードにサンプルが収録されています。ダウンロードの目次を表示させたら、「AbsolutePage, PageSize, PageCountプロパティを利用した手法」をクリックしてください。Internet Explorerの左側のフレームには、ASPのソースが表示されます。右側のフレームには、実行結果が表示されます。

リストの行43では、intPageSizeにページ当たりのレコード件数10を設定しています。このサンプルでは、１ページ当たり10レコード表示します。

43: intPageSize = 10

行45-49では、RequestオブジェクトのQueryStringメソッドでカレントページ(page=)のQueryStringを取得して値を調べています。カレントページのQueryStirngが空白のときは、intPageCurrentに1を設定して初期化します。カレントページのQueryStringが指定されているときは、CInt()関数で整数型に変換してintPageCurrentに保存します。QueryStringは、ページ移動用のハイパーリンクに指定しています。

45: if len(request.QueryString("page")) = 0 then

46: intPageCurrent = 1

47: else

48: intPageCurrent = CInt(request.QueryString("page"))

49: end if

行51-54では、Accessのデータベースado.mdbを接続するための処理を行っています。行51-52では、OLEDBのProviderとData Sourceを設定してstrConnectionに保存しています。行54では、ConnectionオブジェクトのOpenメソッドでado.mdbを接続しています。

51: strConnection = "Provider=Microsoft.Jet.OLEDB.4.0;" _

52: & "Data Source=" & server.MapPath("webdb/ado.mdb")

53: set cnn = server.CreateObject("adodb.connection")

54: cnn.Open strConnection

行56-58では、得意先テーブルからレコードを抽出するSQLを作成してstrSQLに保存しています。SQLのSELECTのフィールド名には、得意先コード、得意先名、担当者名、電話番号を指定しています。また、このSQLには、ORDER BY句が指定されていますので得意先コード順に並べ替えられます。

56: strSQL = "Select 得意先コード,得意先名,担当者名,電話番号" _

57: & " From 得意先" _

58: & " Order by 得意先コード;"

行60では、ServerオブジェクトのCreateObjectメソッドでRecordsetのインスタンスを生成しています。行61では、RecordsetオブジェクトのPageSizeプロパティにintPageSizeを設定します。intPageSizeには、10が保存されていますので１ページに10レコード表示されます。行62では、RecordsetのCursorLocationプロパティにadUseClientを設定しています。行63では、RecordsetのCashSizeプロパティにintPageSizeを設定しています。（つまり、キャッシュサイズとページサイズを一致させています。）行64-65では、RecordsetのOpenメソッドで得意先テーブルのレコードセットを生成しています。

60: set rs = server.CreateObject("adodb.recordset")

61: rs.PageSize = intPageSize

62: rs.CursorLocation = adUseClient

63: rs.CacheSize = intPageSize

64: rs.Open strSQL, cnn, adOpenStatic, _

65: adLockReadOnly, adCmdText

行66-70では、RecordsetオブジェクトのPageCountプロパティを調べています。PageCountプロパティが0なら、Response.Clearメソッドでバッファの内容を消去してからEchoを呼び出して「レコードがありません！」のメッセージを表示します。最後に、Response.Endメソッドでこのページの処理を終了します。

66: if rs.PageCount = 0 then

67: response.Clear

68: Echo "レコードがありません！"

69: response.End

70: end if

Sub Echoは、行6-8に定義されています。このSubは、引数で指定された文字列をResponse.Writeメソッドでブラウザに送信します。Sub EchoNLは、行9-11に定義されています。このSubは、引数で指定された文字列をResponse.Writeメソッドでブラウザに送信します。このとき、NewLine(CR+LF: Carriage Return + Line Feedの略)も同時に送信します。

行72では、RecordsetオブジェクトのPageCountプロパティをintPageCountに保存しています。このプロパティにはレコードセットの総ページ数が格納されています。

72: intPageCount = rs.PageCount

行74-79では、QueryStringのカレントページがRecordsetの総ページ数の範囲内か調べています。カレントページがRecordsetの総ページ数より大きいときは、カレントページをRecordsetの総ページ数にします。また、カレントページが1より小さいときは、1にします。

74: if intPageCurrent > intPageCount then

75: intPageCurrent = intPageCount

76: end if

77: if intPageCurrent < 1 then

78: intPageCurrent = 1

79: end if

行81では、RecordsetのAbsolutePageプロパティにQueryStringのカレントページを設定します。これでカレントレコードは、QueryStringのカレントページの先頭レコードに位置付けされます。

81: rs.AbsolutePage = intPageCurrent

行82-84では、カレントページと総ページ数を「Page 1 of 6」の形式で表示します。

82: echo "Page <b>" & intPageCurrent _

83: & "</b> of <b>" & intPageCount & "</b>"

84: echoNL"<br><br>"

行86,107では、HTMLの表を作成するために<table>・・・</table>タグを送信しています。

86: EchoNL"<table border='1'>"

・・・

107: EchoNL"</table>"

行87-93では、表の見出しを送信しています。行88-92のfor…nextでは、Recordsetのフィールド名を見出しとして送信しています。

87: EchoNL vbTab & "<tr>"

88: for intI = 0 to rs.Fields.Count - 1

89: Echo vbTab & vbTab & "<th>"

90: Echo rs.Fields(intI).Name

91: EchoNL "</th>"

92: next

93: EchoNL vbTab & "</tr>"

行95-106では、QueryStringのカレントページをブラウザに送信しています。行95では、カレントページに送信したレコード数を0に初期化しています。行96-106のdo while…loopでは、カレントページに表示するレコードを送信しています。行98-102のfor…nextでは、カレントレコードのすべてのフィールドを送信しています。行104では、カレントページに送信したレコード数を+1加算しています。行105では、RecordsetのMoveNextメソッドで次のレコードに移動しています。カレントレコードがカレントページの最終レコードのとき、またはEOFが報告されたときdo while…loopが終了します。

95: intRecordsShown = 0

96: do while intRecordsShown < intPageSize and not rs.EOF

97: EchoNL vbTab & "<tr>"

98: for intI = 0 to rs.Fields.Count - 1

99: Echo vbTab & vbTab & "<td>"

100: Echo rs.fields(intI)

101: EchoNL "</td>"

102: next

103: EchoNL vbTab & "</tr>"

104: intRecordsShown = intRecordsShown + 1

105: rs.MoveNext

106: loop

行109-110では、レコードセットを閉じてデータベースを切断しています。

109: rs.Close

110: cnn.Close

行115-132では、表の最後にページ移動用のハイパーリンク(HTMLの<a>・・・</a>タグ)を生成しています。行115-118では、カレントページが１以上のとき「Prev」のハイパーリンクを生成します。

115: if intPageCurrent > 1 then

116: EchoNL "<a href='RecordsetPaging.asp?page=" _

117: & intPageCurrent - 1 & "'>Prev</a> "

118: end if

行120-127のfor…nextでは、カレントページを除く各ページのハイパーリンクを生成しています。カレントページは、通常のテキストとして表示します。「 」は、印字されない空白でCHR(160)に対応します。HTMLでは、空白CHR(32)を送信しても無視されますが、CHR(160)を送信すると空白が確保されます。

120: for intI = 1 to intPageCount

121: if intI = intPageCurrent then

122: Echo intI & " "

123: else

124: EchoNL "<a href='RecordsetPaging.asp?page=" _

125: & intI & "'>" & intI & "</a> "

126: end if

127: next

行129-132では、カレントページが最終ページ以外のとき「Next」のハイパーリンクを生成しています。

129: if intPageCurrent < intPageCount then

130: EchoNL "<a href='RecordsetPaging.asp?page=" _

131: & intPageCurrent + 1 & "'> Next</a>"

132: end if

図　得意先テーブルのレコードを複数ページに分割して表示するサンプル（その１）

図　得意先テーブルのレコードを複数ページに分割して表示するサンプル（その２）

リスト RecordsetPaging.aspのソースコード

1: <%@ language=vbscript %>

2: <% option explicit %>

3: <% response.buffer = true %>

4:

5: <%

6: sub Echo(strMsg)

7: response.write strMsg

8: end sub

9: sub EchoNL(strMsg)

10: response.write strMsg & vbNewLine

11: end sub

12: %>

13: <html>

14: <head>

15: <style>

16: tr {

17: background: cyan;

18: font-size: 80%;

19: }

20:

21: th {

22: color: blue;

23: }

24:

25: td {

26: color: black;

27: }

28:

29: </style>

30: </head>

31: <body>

32: <%

33: dim cnn, rs

34: dim strSQL

35: dim strConnection

36:

37: dim intPageSize

38: dim intPageCount

39: dim intPageCurrent

40: dim intRecordsShown

41: dim intI

42:

43: intPageSize = 10

44:

45: if len(request.QueryString("page")) = 0 then

46: intPageCurrent = 1

47: else

48: intPageCurrent = cint(request.QueryString("page"))

49: end if

50:

51: strConnection = "Provider=Microsoft.Jet.OLEDB.4.0;" _

52: & "Data Source=" & server.MapPath("webdb/ado.mdb")

53: set cnn = server.CreateObject("adodb.connection")

54: cnn.open strConnection

55:

56: strSQL = "Select 得意先コード,得意先名,担当者名,電話番号" _

57: & " From 得意先" _

58: & " Order by 得意先コード;"

59:

60: set rs = server.CreateObject("adodb.recordset")

61: rs.PageSize = intPageSize

62: rs.CursorLocation = adUseClient

63: rs.CacheSize = intPageSize

64: rs.Open strSQL, cnn, adOpenStatic, _

65: adLockReadOnly, adCmdText

66: if rs.PageCount = 0 then

67: response.clear

68: echo "レコードがありません！"

69: response.end

70: end if

71:

72: intPageCount = rs.PageCount

73:

74: if intPageCurrent > intPageCount then

75: intPageCurrent = intPageCount

76: end if

77: if intPageCurrent < 1 then

78: intPageCurrent = 1

79: end if

80:

81: rs.AbsolutePage = intPageCurrent

82: echo "Page <b>" & intPageCurrent _

83: & "</b> of <b>" & intPageCount & "</b>"

84: echoNL"<br><br>"

85:

86: echoNL"<table border='1'>"

87: echoNL vbTab & "<tr>"

88: for intI = 0 to rs.fields.count - 1

89: echo vbTab & vbTab & "<th>"

90: echo rs.fields(intI).name

91: echoNL "</th>"

92: next

93: echoNL vbTab & "</tr>"

94:

95: intRecordsShown = 0

96: do while intRecordsShown < intPageSize and not rs.eof

97: echoNL vbTab & "<tr>"

98: for intI = 0 to rs.fields.count - 1

99: echo vbTab & vbTab & "<td>"

100: echo rs.fields(intI)

101: echoNL "</td>"

102: next

103: echoNL vbTab & "</tr>"

104: intRecordsShown = intRecordsShown + 1

105: rs.MoveNext

106: loop

107: echoNL"</table>"

108:

109: rs.close

110: cnn.close

111: set rs = nothing

112: set cnn = nothing

113:

114: echo "<br>"

115: if intPageCurrent > 1 then

116: echoNL "<a href='RecordsetPaging.asp?page=" _

117: & intPageCurrent - 1 & "'>Prev</a> "

118: end if

119:

120: for intI = 1 to intPageCount

121: if intI = intPageCurrent then

122: echo intI & " "

123: else

124: echoNL "<a href='RecordsetPaging.asp?page=" _

125: & intI & "'>" & intI & "</a> "

126: end if

127: next

128:

129: if intPageCurrent < intPageCount then

130: echoNL "<a href='RecordsetPaging.asp?page=" _

131: & intPageCurrent + 1 & "'> Next</a>"

132: end if

133: %>

134: </body>

135: </html>

● ページ当たりのレコード数を可変とするサンプル

ここで紹介するサンプルは、得意先テーブルのレコードセットを複数のページに分割して表示するとき、ページ当たりのレコード数をドロップダウンリストから選択することができます。さらに、レコードセットを得意先コード順、またはフリガナ順に並べ替えて表示させることができます。

Access + Webのダウンロードにサンプルが収録されています。ダウンロードの目次を表示させたら、「ページサイズ、ソート順を任意に選択可能とした例」をクリックしてください。Internet Explorerの左側のフレームには、ASPのソースが表示されます。右側のフレームには、実行結果が表示されます。

リストにサンプルのソースを掲載していますが、網がけの部分が追加／変更された箇所です。ここでは、追加変更された箇所を中心に説明します。

行49-65では、RequestオブジェクトのQueryStringメソッドでpage=, pagesize=, order=のQueryStringを取得しています。これらのQueryStringは、ページ移動用のハイパーリンクで設定しています。再設定のボタンをクリックしたときは、ドロップダウンリストから選択したpagesizeと orderが自動的にQueryStringに設定されます。行49-53では、page=のQueryStringを取得してintPageCurrentに保存しています。行55-59では、pagesize=のQueryStirngを取得してintPageSizeに保存しています。行61-65では、order=のQueryStringを取得してstrOrderByに保存しています。order=には、「得意先コード」または「フリガナ」が指定されますが、URLEncodeされています。たとえば、「得意先コード」の場合、以下のようにURLEncodeされて渡されます。

order=%93%BE%88%D3%90%E6%83R%81%5B%83h

Server.QueryStringメソッドで、order=のQueryStringを取得すると自動的にDecodeされて「得意先コード」が返されます。

・・・

49: if len(request.QueryString("page")) = 0 then

50: intPageCurrent = 1

51: else

52: intPageCurrent = CInt(request.QueryString("page"))

53: end if

54:

55: if len(request.QueryString("pagesize")) = 0 then

56: intPageSize = 10

57: else

58: intPageSize = CInt(request.QueryString("pagesize"))

59: end if

60:

61: if len(request.QueryString("order")) = 0 then

62: strOrderBy = "得意先コード"

63: else

64: strOrderBy = request.QueryString("order")

65: end if

行72-74で得意先テーブルからレコードを取得するSQLを作成するとき、ORDER BY句には、QueryStirngのorder=で指定されているフィールド名を使用します。

72: strSQL = "Select 得意先コード,得意先名,担当者名,電話番号" _

73: & " From 得意先" _

74: & " Order by " & strOrderBy & ";"

行135-141では、カレントページが1以上のときPrevのハイパーリンクを生成します。行139では、ServerオブジェクトのURLEncodeメソッドでstrOrderByをURLEncodeしています。strOrderByには、「得意先コード」または「フリガナ」が格納されています。漢字をQueryStringに指定するときは、URLEncodeした値を指定する必要があります。（Internet Explorerなどの最新のブラウザでは、自動的にURLEncodeしますが他のブラウザでは保障されません。）

135: if intPageCurrent > 1 then

136: echoNL "<a href='RecordsetPaging2.asp?page=" _

137: & intPageCurrent - 1 _

138: & "&pagesize=" & intPageSize _

139: & "&order=" & Server.URLEncode(strOrderBy) _

140: & "'>Prev</a> "

141: end if

行143-152のfor…nextでは、カレントページを除く各ページのハイパーリンクを生成しています。行149では、strOrderByをURLEncodeしています。

143: for intI = 1 to intPageCount

144: if intI = intPageCurrent then

145: echoNL intI & " "

146: else

147: echoNL "<a href='RecordsetPaging2.asp?page=" & intI _

148: & "&pagesize=" & intPageSize _

149: & "&order=" & Server.URLEncode(strOrderBy) & "'>" _

150: & intI & "</a> "

151: end if

152: next

行154-159では、カレントページが最終ページ以外のときNextのハイパーリンクを生成しています。行158では、strOrderByをURLEncodeしています。

154: if intPageCurrent < intPageCount then

155: echoNL "<a href='RecordsetPaging2.asp?page=" _

156: & intPageCurrent + 1 _

157: & "&pagesize=" & intPageSize _

158: & "&order=" & Server.URLEncode(strOrderBy) & "'> Next</a>"

159: end if

行162, 198では、HTMLの<form>・・・</form>タグを定義しています。<form>タグのmethod=に”get”が指定されていますのでドロップダウンリストで選択したページサイズとソート順は、QueryStringとして渡されます。QueryStringは、action=で指定したASPファイルに付加されます。

RecordsetPaging2.asp?pagesize=10&order=・・・

162: <form action="RecordsetPaging2.asp" method="get">

・・・

198: </form>

行165-176では、HTMLの<select>・・・</select>タグを生成しています。行167-174のfor…nextでは、ドロップダウンリストのアイテムを生成しています。行169-171では、前回選択したアイテムをデフォルト表示させています。アイテムをデフォルト表示させるには、<option>タグにselectedを挿入します。

・・・

165: <select size="1" name="pagesize">

166: <%

167: for intI = 5 to 10 step 1

168: strOption = "<option value='" & intI & "'"

169: if intI = intPageSize then

170: strOption = strOption & " selected"

171: end if

172: strOption = strOption & ">" & intI & "行</option>"

173: EchoNL strOption

174: next

175: %>

176: </select>

行179-194では、ソート順のドロップダウンリストを生成しています。

<option value="得意先コード" selected>得意先コード</option>

</select>

179: <select size="1" name="order">

180: <option value="得意先コード"

181: <%

182: if strOrderBy = "得意先コード" then

183: echo " selected"

184: end if

185: %>

186: >得意先コード</option>

187: <option value="フリガナ"

188: <%

189: if strOrderBy = "フリガナ" then

190: echo " selected"

191: end if

192: %>

193: >フリガナ</option>

194: </select>

行196では、再設定のボタンを定義しています。再設定のボタンをクリックすると、<form>タグのaction=で指定したRecordsetPaging2.aspがロードされます。ドロップダウンリストから選択したページサイズとソート順は、QueryStringとして渡されます。

196: <input type="submit" value="再設定">

図　ページ当たりのレコード数を可変としたサンプル（その１）

図ページ当たりのレコード数を可変としたサンプル（その２）

リスト　RecordsetPaging2.aspのソースコード

1: <%@ language=vbscript %>

2: <% option explicit %>

3:

4: <%

5: sub Echo(strMsg)

6: response.write strMsg

7: end sub

8: sub EchoNL(strMsg)

9: response.write strMsg & vbNewLine

10: end sub

11: %>

12: <html>

13: <head>

14: <style>

15: tr {

16: background: cyan;

17: font-size: 80%;

18: }

19:

20: th {

21: color: blue;

22: }

23:

24: td {

25: color: black;

26: }

27:

28: span {

29: font-family: "ＭＳゴシック";

30: font-size: 80%;

31: }

32:

33: </style>

34: </head>

35: <body>

36: <%

37: dim cnn, rs, fld

38: dim strSQL

39: dim strConnection

40:

41: dim intPageSize

42: dim intPageCount

43: dim intPageCurrent

44: dim strOrderBy

45: dim intRecordsShown

46: dim intI

47: dim strOption

48:

49: if len(request.QueryString("page")) = 0 then

50: intPageCurrent = 1

51: else

52: intPageCurrent = cint(request.QueryString("page"))

53: end if

54:

55: if len(request.QueryString("pagesize")) = 0 then

56: intPageSize = 10

57: else

58: intPageSize = cint(request.QueryString("pagesize"))

59: end if

60:

61: if len(request.QueryString("order")) = 0 then

62: strOrderBy = "得意先コード"

63: else

64: strOrderBy = request.QueryString("order")

65: end if

66:

67: strConnection = "Provider=Microsoft.Jet.OLEDB.4.0;" _

68: & "Data Source=" & server.MapPath("webdb/ado.mdb")

69: set cnn = server.CreateObject("adodb.connection")

70: cnn.open strConnection

71:

72: strSQL = "Select 得意先コード,得意先名,担当者名,電話番号" _

73: & " From 得意先" _

74: & " Order by " & strOrderBy & ";"

75:

76: set rs = server.CreateObject("adodb.recordset")

77: with rs

78: .PageSize = intPageSize

79: .CursorLocation = adUseClient

80: .CacheSize = intPageSize

81: .Open strSQL, cnn, adOpenStatic, _

82: adLockReadOnly, adCmdText

83: intPageCount = .PageCount

84: if intPageCount = 0 then

85: rs.close

86: cnn.close

87: set rs = nothing

88: set cnn = nothing

89: response.clear

90: echo "レコードがありません！"

91: response.end

92: end if

93:

94: if intPageCurrent > intPageCount then

95: intPageCurrent = intPageCount

96: end if

97: if intPageCurrent < 1 then

98: intPageCurrent = 1

99: end if

100:

101: .AbsolutePage = intPageCurrent

102: echo "Page <b>" & intPageCurrent _

103: & "</b> of <b>" & intPageCount & "</b>"

104: echoNL "<br><br>"

105:

106: echoNL "<table border='1'>"

107: echoNL vbTab & "<tr>"

108: for each fld in .fields

109: echo vbTab & vbTab & "<th>"

110: echo fld.name

111: echoNL "</th>"

112: next

113: echoNL vbTab & "</tr>"

114:

115: intRecordsShown = 0

116: do while intRecordsShown < intPageSize and not .eof

117: echoNL vbTab & "<tr>"

118: for each fld in .fields

119: echo vbTab & vbTab & "<td>"

120: echo fld.value

121: echoNL "</td>"

122: next

123: echoNL vbTab & "</tr>"

124: intRecordsShown = intRecordsShown + 1

125: .MoveNext

126: loop

127: echoNL "</table>"

128: end with

129: rs.close

130: cnn.close

131: set rs = nothing

132: set cnn = nothing

133:

134: echoNL "<br>"